project(bladerf1output)

set(bladerf1output_SOURCES
	bladerf1output.cpp
	bladerf1outputplugin.cpp
    bladerf1outputsettings.cpp
    bladerf1outputwebapiadapter.cpp
	bladerf1outputthread.cpp
)

set(bladerf1output_HEADERS
	bladerf1output.h
	bladerf1soutputplugin.h
    bladerf1outputsettings.h
    bladerf1outputwebapiadapter.h
	bladerf1outputthread.h
)

include_directories(
        ${CMAKE_SOURCE_DIR}/swagger/sdrangel/code/qt5/client
	${CMAKE_SOURCE_DIR}/devices
	${LIBBLADERF_INCLUDE_DIRS}
)

if(NOT SERVER_MODE)
    set(bladerf1output_SOURCES
        ${bladerf1output_SOURCES}
        bladerf1outputgui.cpp

        bladerf1outputgui.ui
    )
    set(bladerf1output_HEADERS
        ${bladerf1output_HEADERS}
        bladerf1outputgui.h
    )

    set(TARGET_NAME ${PLUGINS_PREFIX}outputbladerf1)
    set(TARGET_LIB "Qt::Widgets")
    set(TARGET_LIB_GUI "sdrgui")
    set(INSTALL_FOLDER ${INSTALL_PLUGINS_DIR})
else()
    set(TARGET_NAME ${PLUGINSSRV_PREFIX}outputbladerf1srv)
    set(TARGET_LIB "")
    set(TARGET_LIB_GUI "")
    set(INSTALL_FOLDER ${INSTALL_PLUGINSSRV_DIR})
endif()

if(NOT Qt6_FOUND)
    add_library(${TARGET_NAME} ${bladerf1output_SOURCES})
else()
    qt_add_plugin(${TARGET_NAME} CLASS_NAME Bladerf1OutputPlugin)
    target_sources(${TARGET_NAME} PRIVATE ${bladerf1output_SOURCES})
endif()

if(NOT BUILD_SHARED_LIBS)
    set_property(GLOBAL APPEND PROPERTY STATIC_PLUGINS_PROPERTY ${TARGET_NAME})
endif()

if(LIBBLADERF_EXTERNAL)
    add_dependencies(${TARGET_NAME} bladerf)
endif()

target_link_libraries(${TARGET_NAME} PRIVATE
        Qt::Core
        ${TARGET_LIB}
	sdrbase
	${TARGET_LIB_GUI}
        swagger
        ${LIBBLADERF_LIBRARIES}
        bladerf1device
)

install(TARGETS ${TARGET_NAME} DESTINATION ${INSTALL_FOLDER})

# Install debug symbols
if (WIN32)
    install(FILES $<TARGET_PROPERTY:${TARGET_NAME},RUNTIME_OUTPUT_DIRECTORY>/${TARGET_NAME}stripped.pdb CONFIGURATIONS Release DESTINATION ${INSTALL_FOLDER} RENAME ${TARGET_NAME}.pdb )
    install(FILES $<TARGET_PDB_FILE:${TARGET_NAME}> CONFIGURATIONS Debug RelWithDebInfo DESTINATION ${INSTALL_FOLDER} )
endif()
